Выберите 1-ый элемент только - с условием использования XML :: Twig

Question

Имея этот код:

#!/usr/bin/env perl 
use 5.014; 
use warnings; 
use XML::Twig; 

my $twig = XML::Twig->parse(\*DATA); 
$twig->set_pretty_print('indented_a'); 

# 1st search 
# this prints OK the all <files> nodes where the <type> == 'release' 
$_->print for ($twig->findnodes('//type[string()="release"]/..')); 

# 2nd search  
# try to get first matched only 
my $latest = $twig->findnodes('(//type[string()="release"])[1]/..'); 
$latest->print; 

__DATA__ 
<root> 
    <files> 
     <type>beta</type> 
     <ver>3.0</ver> 
    </files> 
    <files> 
     <type>alpha</type> 
     <ver>3.0</ver> 
    </files> 
    <files> 
     <type>release</type> 
     <ver>2.0</ver> 
    </files> 
    <files> 
     <type>release</type> 
     <ver>1.0</ver> 
    </files> 
</root> 

Вышеприведенные принты

<files> 
    <type>release</type> 
    <ver>2.0</ver> 
    </files> 
    <files> 
    <type>release</type> 
    <ver>1.0</ver> 
    </files> 
error in xpath expression (//type[string()="release"])[1]/.. around (//type[string()="release"])[1]/.. at /opt/anyenv/envs/plenv/versions/5.24.0/lib/perl5/site_perl/5.24.0/XML/Twig.pm line 3648. 

разыскиваемого выход из 2-й категории

<files> 
     <type>release</type> 
     <ver>2.0</ver> 
    </files> 

например первый узел <files>, где <type> eq 'release'.

В соответствии с this answer используемое выражение XPath (//type[string()="release"])[1]/..' должно работать, но, похоже, я снова пропустил что-то важное.

Не могли бы помочь, пожалуйста?

Answer 1

XML::Twig не поддерживает полный синтаксис XPath. Документация для get_xpath метода (так же, как findnodes) говорит, что это

Подмножество сокращенного синтаксиса XPATH покрыта:

tag 
tag[1] (or any other positive number) 
tag[last()] 
tag[@att] (the attribute exists for the element) 
tag[@att="val"] 
tag[@att=~ /regexp/] 
tag[att1="val1" and att2="val2"] 
tag[att1="val1" or att2="val2"] 
tag[string()="toto"] (returns tag elements which text (as per the text method) 
        is toto) 
tag[string()=~/regexp/] (returns tag elements which text (as per the text 
         method) matches regexp) 
expressions can start with/(search starts at the document root) 
expressions can start with . (search starts at the current element) 
// can be used to get all descendants instead of just direct children 
* matches any tag 

Так подвыражение в скобках, не поддерживается, и вы может указывать только один предикат

Также важно, чтобы в скалярном контексте findnodes возвращал только количество найденных узлов. Вы должны использовать его в контексте списка, чтобы получить Узлы самих, что означает, что более простой способ найти только первый соответствующий элемент должен написать

my ($latest) = $twig->findnodes('//type[string()="release"]/..'); 

, который прекрасно работает

Если вам действительно нужна полная мощность XPath, тогда вы можете использовать XML::Twig::XPath. Этот модуль использует либо XML::XPath, либо отличный XML::XPathEngine, чтобы обеспечить полный синтаксис XPath путем перегрузки findnodes. (Другие методы get_xpath и find_nodes продолжать использовать пониженную XML::Twig вариации.)

findnodes в скалярном контексте теперь возвращает XML::XPathEngine::NodeSet объект, который имеет индексацию массива перегружен.Таким образом, вы можете написать

my $latest = $twig->findnodes('//type[string()="release"]/..'); 
$latest->[0]->print; 

или просто

my ($latest) = $twig->findnodes('//type[string()="release"]/..'); 

, как указано выше.

Наконец, я предпочел бы видеть /root/files[type[string()="release"]] в предпочтении к заднему parent::node(), но это сугубо личное

Answer 2

XML :: Twig не поддерживает весь XPath. Выражение работает правильно в XML::LibXML.

Вы можете ходить структуру самостоятельно в Perl:

my $latest = ($twig->findnodes('//type[string()="release"]'))[0]->parent; 

Answer 3

XML :: Twig не поддерживает все XPath, но XML :: Twig :: XPath делает.

Так use XML::Twig::XPath;, то my $twig = XML::Twig::XPath->parse(... и вуаля ... теперь вы можете получить до фиксации $latest=... линии, которая должна быть:

my $latest = ($twig->findnodes('(//type[string()="release"])[1]/..'))[0]; 

(как вы его $ последняя является XML::XPathEngine::NodeSet, что вам нужно возьмем первый элемент этого множества).