Можно использовать функцию агрегата при вставке данных в SPARQL?

Question

я следующий запрос, который направлен на предотвращение вставки в имени графа, когда количество троек из заданного числа, например 5.

Я попытался воспроизвести пример показал here где вставка данных возможно, но мне нужно использовать один и тот же граф и, самое главное, агрегированную функцию, то есть COUNT.

INSERT 
    { 
    GRAPH <http://example/g1> { ?s ?p ?o } 
    } 
WHERE 
    { 
    GRAPH <http://example/g1> 
    { 
    ?s ?p ?o . 
    FILTER (COUNT(?p) < 5) 
    } 
} 

Jena фусеки вызывает следующую ошибку:

Aggregate expression not legal at this point 

Answer 1

Да, это возможно:

INSERT 
    { 
    GRAPH <http://example/g2> { ?s ?p ?o } 
    } 
WHERE 
{ 
    GRAPH <http://example/g1> { 
    ?s ?p ?o .   # select all triples 
    { SELECT ?s   # do a check for the selected subject 
     WHERE { GRAPH <http://example/g1> { ?s ?p ?o } } 
     GROUP BY ?s   # count properties per subject 
     HAVING (COUNT(?p) < 5) # only subjects with less than 5 properties 
    } 
    } 
} 

Прежде всего, агрегатные операторы не могут быть размещены внутри пункта FILTER, чтобы использовать их в качестве условного вы должны поместить их в предложение HAVING.

Кроме того, поскольку вы хотите подсчитать свойства объекта, вы должны использовать GROUP BY ?s и использовать подзапрос (который проверяет ограничение количества свойств объекта) в сочетании с простым совпадением шаблонов.

EDIT Обратите внимание, что я слегка измененный исходное обновление: это вставки в другой именем графа от того, которую вы запрашиваете. Разумеется, вставка в один и тот же граф будет работать, но результаты не будут наблюдаемыми (поскольку вы просто вставляете те же данные, которые уже присутствовали на этом графике).