Удалить строку, если первая ячейка не является числовым VBA Excel

Question

Я использую следующий код, чтобы удалить строку, если первая ячейка не является числом (текст или пустые ячейки)

Dim LR3 As Long, i3 As Long 
With Sheets("Productos") 
LR3 = Range("A" & Rows.Count).End(xlUp).Row 
For i3 = LR3 To 2 Step -1 
    If IsNumeric(Sheets("Productos").Range("A" & i3).Value) Then 
    Else 
    Rows(i3).Delete 
    End If 
Next i3 
End With 

LR3 до 2 используется, потому что первая строка - строка заголовка, и я не хочу, чтобы она была удалена. Я не вижу ничего плохого в коде, и я даже не ошибаюсь. Вы видите что-то не так? Это может быть ложная процедура?

Answer 1

Проблема с вашим кодом, который, как я подозреваю, заключается в том, что Sheets("Productos") не является активом. Таким образом, Rows(i3).Delete имеет в виду действующую схему, которая может не быть Sheets("Productos")

Обратите внимание на использование ДОТС в приведенном ниже коде.

Попробуйте это (испытанный)

Sub Sample() 
    Dim LR3 As Long, i3 As Long 

    With Sheets("Productos") 
     LR3 = .Range("A" & .Rows.Count).End(xlUp).Row 

     For i3 = LR3 To 2 Step -1 
      If Not IsNumeric(.Range("A" & i3).Value) Then .Rows(i3).Delete 
     Next i3 
    End With 
End Sub 

EDIT: Я пропустил пустые ячейки часть, но благодаря сообщению Джимми, я увидел, что.

Измененный Кодекс

Sub Sample() 
    Dim LR3 As Long, i3 As Long 

    With Sheets("Productos") 
     LR3 = .Range("A" & .Rows.Count).End(xlUp).Row 

     For i3 = LR3 To 2 Step -1 
      If Not IsNumeric(.Range("A" & i3).Value) Or _ 
      .Range("A" & i3).Value = "" Then .Rows(i3).Delete 
     Next i3 
    End With 
End Sub 

Answer 2

Если ячейка пуста, IsNumeric возвращает истину. Вы можете попробовать использовать len,

Dim LR3 As Long, i3 As Long 

With Sheets("Productos") 
    LR3 = .Range("A" & .Rows.Count).End(xlUp).Row 

    For i3 = LR3 To 2 Step -1 
     If IsNumeric(.Range("A" & i3).Value) And _ 
     len(.Range("A" & i3).Value) > 0 Then 

     Else 
      .Rows(i3).Delete 
     End If 
    Next i3 
End With