Scheme - серия фибоначчи с вложенной лямбдой

Question

Вдохновленный this пост.

Я пытаюсь реализовать ряд Фибоначчи с вложенным лямбда -

(((lambda (x) (x x)) ;; evaluate x on x 
    ((lambda (fibo-gen)) ;; fibo-gen get another func as arg 
    (lambda (N it second first) 
    (cond ;; here the body of the above func .. 
     ((= N 1) 1) 
     ((= N 1) 1) 
     ((= N it) (+ second first)) 
     (else (fibo-gen (+ it 1) (+ second first) (second))) 
     ) 
    ) 
    ) 
    ) 
5 1 1 1) 

Это предлагающее r5rs:body: no expression in body in: (r5rs:body)

По моей экспертизе каждая функция имеет «тело» здесь, так что я сделал не так?

Обратите внимание, что реализация я пытаюсь сделать здесь является итеративным режим, который избежать повторного вычисления предыдущей серии ..

Edit:

Другой режим, который также работает -

(((lambda (x) (x x)) ;; evaluate x on x 
    (lambda (fibo-gen) ;; fibo-gen body use another lambda .. 
    (lambda (N it second first) 
    (cond ;; here the body of the above func .. 
     ((= N 1) 1) 
     ((= N 2) 1) 
     ((= N it) second) 
     (else ((fibo-gen fibo-gen) N (+ it 1) (+ second first) second)) 
     ) 
    ) 
    ) 
    ) 
5 1 1 1) 
=> 8 

Answer 1

Ну, это довольно - изобретательный способ расчета фибоначчи, но тем не менее возможно:

(((lambda (x) (x x)) 
    (lambda (fib-gen) 
    (lambda (it second first) 
     (if (zero? it) 
      first 
      ((fib-gen fib-gen) (sub1 it) (+ first second) second))))) 
10 1 0) ; here n = 10 

=> 55 

Если вы стремитесь к общему пути для написания рекурсивной функции без использования define, первой реализация Y-Combinator:

(define (Y X) 
    ((lambda (proc) (proc proc)) 
    (lambda (proc) 
    (X (lambda args 
      (apply (proc proc) args)))))) 

С этим, вы можете написать анонимные рекурсивные процедуры с переменным числом аргументов , например:

((Y 
    (lambda (fib-gen) 
    (lambda (it second first) 
     (if (zero? it) 
      first 
      (fib-gen (sub1 it) (+ first second) second))))) 
10 1 0) ; here n = 10 

=> 55 

Answer 2

(lambda (fibo-gen)) 

во второй строке не имеет тела.