XSLT 1.0 Использование Содержит с набором внешнего набора параметров

Question

Я пытаюсь сравнить текст в определенном узле (EN_PLAN_NAME) со списком строк, чтобы я мог выводить только узлы, содержащие текст, соответствующий одной из этих строк. Я попытался с помощью ответа от этого подобного вопроса:

How to compare against multiple strings in xslt

ВХОДА XML

<EligibilityRecords xmlns="http://CDHC_Eligibility_LSDD"> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>Health Savings Account</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>zzHealth Reimbursement Arrangement</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>Health Reimbursement Arrangement 233</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>HRA</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>BASE HRA</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>FSA</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
</EligibilityRecords> 

ЗАПЛАНИРОВАННЫХ XML

<EligibilityRecords xmlns="CDHC_Eligibility_LSDD_Internal"> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>zzHealth Reimbursement Arrangement</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>Health Reimbursement Arrangement 233</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>HRA</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
    <Eligibility_Detail_Record xmlns=""> 
    <EN_PLAN_NAME>BASE HRA</EN_PLAN_NAME> 
    <EN_MBRSHP_EFF_STRT_DT>01012017</EN_MBRSHP_EFF_STRT_DT> 
    </Eligibility_Detail_Record> 
</EligibilityRecords> 

XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
       xmlns:var="http://schemas.microsoft.com/BizTalk/2003/var" 
       exclude-result-prefixes="msxsl var s0 ns0" version="1.0" 
       xmlns:s0="CDHC_Eligibility_LSDD" 
       xmlns:ns0="CDHC_Eligibility_LSDD_Internal"> 
    <xsl:output omit-xml-declaration="yes" method="xml" version="1.0" /> 

    <xsl:param name="HRAPlanNames"> 
     <PlanName>Health Reimbursement Arrangement</PlanName> 
     <PlanName>HRA</PlanName> 
    </xsl:param> 

    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="/*"> 
    <ns0:EligibilityRecords> 
     <xsl:for-each select="Eligibility_Detail_Record"> 
     <xsl:if test="contains(EN_PLAN_NAME,msxsl:node-set($HRAPlanNames)/*)"> 
      <Eligibility_Detail_Record> 
      <xsl:copy-of select="EN_PLAN_NAME"/> 
      </Eligibility_Detail_Record> 
     </xsl:if> 
     </xsl:for-each> 
    </ns0:EligibilityRecords> 
    </xsl:template> 
</xsl:stylesheet> 

XSLT- выводит любую EN_PLAN_NAME, который имеет текст, содержащий «Здоровье Компенсация Композиция», но не выводит какой-либо узел, который содержит «HRA». Я не уверен, что я делаю неправильно.

Answer 1

Примечание: вы можете взять translate() из обоих примеров. Я скопировал вход с вашего вопроса перед редактированием.

я не могу проверить msxsl прямо сейчас, но попробуйте это:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
    xmlns:var="http://schemas.microsoft.com/BizTalk/2003/var" 
    exclude-result-prefixes="msxsl var s0 ns0" version="1.0" 
    xmlns:s0="CDHC_Eligibility_LSDD" 
    xmlns:ns0="CDHC_Eligibility_LSDD_Internal"> 
    <xsl:output omit-xml-declaration="yes" method="xml" version="1.0" /> 

    <xsl:param name="HRAPlanNames"> 
    <PlanName>HEALTH REIMBURSEMENT ARRANGEMENT</PlanName> 
    <PlanName>HRA</PlanName> 
    </xsl:param> 

    <xsl:variable name="lowercase">abcdefghijklmnopqrstuvwxyz</xsl:variable> 
    <xsl:variable name="uppercase">ABCDEFGHIJKLMNOPQRSTUVWXYZ</xsl:variable> 

    <xsl:template match="/*"> 
    <xsl:copy> 
     <xsl:for-each select="Eligibility_Detail_Record"> 
     <xsl:variable name="pn" select="translate(EN_PLAN_NAME,$lowercase,$uppercase)"/> 
     <xsl:if test="msxsl:node-set($HRAPlanNames)/*[contains($pn,normalize-space())]"> 
      <Eligibility_Detail_Record> 
      <xsl:copy-of select="EN_PLAN_NAME"/> 
      </Eligibility_Detail_Record> 
     </xsl:if> 
     </xsl:for-each> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Если это не работает, и вы не против названия плана, который жестко закодированы в XSLT (не используется xsl:param), попробовать что-то, что не использует node-set():

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
    xmlns:var="http://schemas.microsoft.com/BizTalk/2003/var" 
    exclude-result-prefixes="msxsl var s0 ns0 local" version="1.0" 
    xmlns:s0="CDHC_Eligibility_LSDD" 
    xmlns:ns0="CDHC_Eligibility_LSDD_Internal" 
    xmlns:local="local"> 
    <xsl:output omit-xml-declaration="yes" method="xml" version="1.0" /> 

    <local:HRAPlanNames> 
    <local:PlanName>HEALTH REIMBURSEMENT ARRANGEMENT</local:PlanName> 
    <local:PlanName>HRA</local:PlanName> 
    </local:HRAPlanNames> 

    <xsl:variable name="planNames" 
    select="document('')/xsl:stylesheet/local:HRAPlanNames/local:PlanName"/> 

    <xsl:variable name="lowercase">abcdefghijklmnopqrstuvwxyz</xsl:variable> 
    <xsl:variable name="uppercase">ABCDEFGHIJKLMNOPQRSTUVWXYZ</xsl:variable> 

    <xsl:template match="/*"> 
    <xsl:copy> 
     <xsl:for-each select="Eligibility_Detail_Record"> 
     <xsl:variable name="pn" select="translate(EN_PLAN_NAME,$lowercase,$uppercase)"/> 
     <xsl:if test="$planNames[contains($pn,normalize-space())]"> 
      <Eligibility_Detail_Record> 
      <xsl:copy-of select="EN_PLAN_NAME"/> 
      </Eligibility_Detail_Record> 
     </xsl:if> 
     </xsl:for-each> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 2

Тип обоих аргументов функции должны быть строка. Вы пытаетесь использовать его с набором узлов в качестве второго аргумента, и (в XSLT 1.0) это приведет к рассмотрению только первого узла в рассматриваемом узле.

Если вы хотите сохранить текущую структуру параметра HRAPlanNames, вам нужно будет сделать что-то вроде:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
exclude-result-prefixes="msxsl" > 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="HRAPlanNames"> 
     <PlanName>Health Reimbursement Arrangement</PlanName> 
     <PlanName>HRA</PlanName> 
</xsl:param> 

<xsl:template match="/*"> 
    <EligibilityRecords xmlns="CDHC_Eligibility_LSDD_Internal"> 
     <xsl:for-each select="Eligibility_Detail_Record"> 
      <xsl:variable name="plan-name" select="EN_PLAN_NAME" /> 
      <xsl:variable name="test"> 
       <xsl:for-each select="msxsl:node-set($HRAPlanNames)/PlanName"> 
        <xsl:if test="contains($plan-name, .)">Y</xsl:if> 
       </xsl:for-each> 
      </xsl:variable> 
      <xsl:if test="string($test)"> 
       <xsl:copy-of select="."/> 
      </xsl:if> 
     </xsl:for-each> 
    </EligibilityRecords> 
</xsl:template> 

</xsl:stylesheet> 

для того, чтобы получить ожидаемый результат.