as3 - получение символов библиотеки из класса Assets

Question

Я создал файл assets.swf, в котором я хочу сохранить все свои символы. Затем я создал класс Assets, который выполняет вложение. Это выглядит следующим образом:

public class Assets extends MovieClip 
    { 
     [Embed(source="assets.swf", symbol="MyBox")] 
     public static var MyBox:Class; 

     public function Assets() 
     { 

     } 

    } 

Теперь, в каком-то другом классе, я хочу создать новую коробку:

import com.company.Assets; 
... 
public function Game() 
{ 

    var myBox:MovieClip = new Assets.MyBox(); 
    addChild(myBox); 

} 

Я знаю, это неправильно, и я получаю «TypeError: Error # 1007: Мгновенное действие было предпринято для неконструктора. " Как получить доступ к активам в классе «Активы»?

Answer 1

Редактировать: Я думаю, вы найдете ответ here.

Для использования классов из SWF, загруженного с классом Loader, применяется следующее.

private function onLoad(e:Event):void 
{ 
var domain:ApplicationDomain = LoaderInfo(e.target).applicationDomain; 
var Type:Class = domain.getDefinition("pack.MyComponent") as Class; 
var myBox:MovieClip = new Type(); 
addChild(myBox); 
} 

Answer 2

Еще один хороший способ добиться этого - просто скомпилировать SWC и импортировать его точно так же, как другой класс.

Каждый символ, экспортированный для AS внутри вашего SWC, будет доступен вам в той же области.

Это экономит много кода, записывая и вставляя активы непосредственно внутри вашего SWF, избегая нескольких загрузчиков.

Answer 3

Если вы все еще хотите маршрут .swf, вы можете:

public class Assets extends MovieClip 
    { 
     [Embed(source="assets.swf", symbol="MyBox")] 
     private static var _MyBox:Class; 
     public static function get NewBox():MovieClip { 
      return new _MyBox(); 
     } 
    } 
... 

import com.company.Assets; 
... 
public function Game() 
{ 

    var myBox:MovieClip = Assets.NewBox; 
    addChild(myBox); 

} 

Альтернативой экспортировать символы, которые вы хотите использовать с помощью Action Script и использовать .swc вместо этого. Вы можете установить классы с полным пространством имен внутри флэш файла, поэтому для MyBox вы могли бы сделать его com.company.Assets.MyBox и использование было бы похоже на то, что вы хотели:

import com.company.Assets.*; 
... 
public function Game() 
{ 

    var myBox:MovieClip = new MyBox(); 
    addChild(myBox); 

} 

Answer 4

Вы можете создать новый объекты в классе активов .. (что дает вам также возможность сделать пул повторно используемых активов)

что-то вроде:

public class Assets extends MovieClip 
{ 
    [Embed(source="assets.swf", symbol="MyBox")] 
    private static var MyBox:Class; 

    public static function getNewBox():DisplayObject { 
     return new MyBox(); 
    } 

    public function Assets() 
    { 

    } 
}