Поиск в файлах в прологе

Question

привет, я пытался создать код, который мог бы найти данный символ из входного файла и распечатать его позицию, вот что я вышел с помощью «с помощью подобных проблем, которые я нашел»,

process2(Text,POS):- 
    open('houses.txt', read, In), 
    get_char(In, Char1), 
    find(Char1, In,Text,POS), 
    close(In). 

find(Text,In, Text, 0). 
find(Char,In,Text,POS) :- 
    POS is POS1 +1, 
    get_char(In, Char2), 
    find(Char2,In,Text,POS1). 

однако компилятор выдает эту ошибку: оШИБКА: есть/2: аргументы не достаточно инстанцирован

Answer 1

при обработке ввода, всегда считают DCG первым:

 
:- use_module(library(pio)). 

process3(File, Text, POS) :- phrase_from_file(find(Text, POS), File). 

find(Text, [P|Ps]) --> 
    lazy_list_character_count (P), Text, !, 
    find(Text, Ps). 
find(Text, Ps) --> [_], find(Text, Ps). 
find(_Text, []) --> []. 

Это находит все позиции входной строки:

?- process3('/home/carlo/.swiplrc', `file`, P). 
P = [51, 174, 254, 452, 549, 1977, 2106, 3682, 4033|...] ; 
false. 

редактировать как предложил Борис, покрой может удалить некоторые законные решения. Итак, вот вырезанная бесплатная версия.

find(_Text, []) --> []. 
find(Text, [P|Ps]) --> 
    lazy_list_character_count(P), Text, 
    find(Text, Ps). 
find(Text, Ps) --> \+Text, [_], find(Text, Ps). 

Answer 2

Это работает точно так же, как и ожидалось, если вы просто используете CLP (FD) ограничения вместо низкоуровневого арифметики:

:- use_module(library(clpfd)). 

find(Text, In, Text, 0). 
find(Char, In, Text, POS) :- 
     POS #= POS1 + 1, 
     get_char(In, Char2), 
     find(Char2,In,Text, POS1). 

Преимущество (FD) версии CLP, что это хвостовая рекурсия , что также вы интуитивно делали.

Я также рекомендую setup_call_cleanup/3, и даже лучше, library(pio) при обработке файлов. (Примечание:! В SICStus Прологе, вы можете установить флаг Пролог double_quotes в chars, а затем использовать DCGs для обработки файла в качестве символов Если вы заинтересованы в этом, лобби для поддержки в SWI)

Я оставляю это, и исправление оставшихся (завершающих) проблем в коде, в качестве упражнений.

Answer 3

Один очень чистый способ сделать это - использовать DCG, например the answer from CapelliC. Как и он, используя изящную library(pio) Ульриха Neumerkel, например as found in SWI-Prolog, вы могли бы объединить DCG и phrase_from_file/2 для следующего решения:

:- use_module(library(pio)). 

... --> []|[_], ... . 

file_pattern_pos(File, Pattern, Pos) :- 
    phrase_from_file((..., 
         lazy_list_character_count(Pos), 
         Pattern, 
         ... 
        ), 
        File). 

Это взято дословно из примера кода в documentation to phrase_from_file/2, просто добавил lazy_list_character_count//1. В отличие от другого ответа DCG, он генерирует все решения при обратном отслеживании. Так с этим файлом:

$ cat banana.txt 
banana 
Antananarivo 

вы получаете от верхнего уровня:

?- file_pattern_pos("banana.txt", "ana", Pos). 
Pos = 1 ; 
Pos = 3 ; 
Pos = 10 ; 
Pos = 12 ; 
false. 

Чтобы составить список всех позиций одного символа:

?- bagof(P, file_pattern_pos("banana.txt", "a", P), Ps). 
Ps = [1, 3, 5, 10, 12, 14]. 

Это решение хорошо , потому что к нему легко добраться, просто просмотрев пример кода из документации до phrase_from_file/2.Однако в приведенных ниже замечаниях были указаны две проблемы:

1. Вопрос об эффективности;
2. Использование lazy_list_character_count//1 означает, что вы не можете использовать это с помощью phrase/2.

Вопрос эффективности может быть решена, как указано в комментарии:

... --> []. 
... --> [_], ... . 

Другой проблемой является более серьезным. В конце концов, возможно, необходимо подсчитать количество потребляемых символов. Например:

span(N) --> span_(0, N). 

span_(N, N) --> []. 
span_(N0, N) --> [_], 
    { N1 is N0 + 1 
    }, 
    span_(N1, N). 

Теперь мы можем написать, с верхнего уровня:

?- phrase_from_file((span(Pos), "ana", ...), "banana.txt"). 
Pos = 1 ; 
Pos = 3 ; 
Pos = 10 ; 
Pos = 12 ; 
false. 

Или, используя phrase/2:

?- phrase((span(P), "ana", ...), "banana"). 
P = 1 ; 
P = 3 ; 
false. 

Answer 4

Если вы намерены с помощью SWI-Пролог, вы можете использовать strings для работы с текстом в более простых случаях. В этом случае, например, достаточно, чтобы прочитать файл из потока In (как у вас есть в вашем вопросе) с помощью read_string/3 и найти позиции всех вхождений подстроки в нем с помощью sub_string/5:

setup_call_cleanup(open(File, read, In), 
        read_string(In, _, File_contents), 
        close(In)), 
sub_string(File_contents, Pos, _Length, _After, Substr) 

Вот и все. Pos будет 0-основанием позиции Substr. Для поиска символов, просто использовать строку длину 1. Одна из лучших вещей о sub_string/5 является то, что он правильно занимается частично перекрывающимися подстроками:

?- sub_string("banana", Pos, _, _, "ana"). 
Pos = 1 ; 
Pos = 3 ; 
false. 

Чем больше стандартным аналогом sub_string/5 является sub_atom/5 с идентичной семантикой как sub_string/5 , но беря атомы. Он должен быть доступен в каждой реализации Prolog.

?- sub_atom(banana, Pos, _, _, ana). 
Pos = 1 ; 
Pos = 3 ; 
false. 

После прочтения всего файла в кодах, просто использовать atom_codes/2 и затем sub_atom/5. Это, однако, несколько расточительно.

Как только вам нужно сделать более сложные вещи с содержимым файла, вы можете перейти к использованию DCG, library(pio) и т. Д. Возвращаясь к использованию примитивов чтения, так как get_char, как правило, не нужно. Тем не менее, я по-прежнему настоятельно рекомендую прочитать раздел руководства по строкам, приведенным выше.