dbms_xmldom - создание xml из базы данных оракула

Question

Я пытаюсь создать xml-файл из базы данных oracle.

Я не могу получить правильный формат и задавался вопросом, смогу ли я получить помощь.

Это часть сценария:

l_record_element := dbms_xmldom.createElement(l_domdoc, 'record_type'); 
dbms_xmldom.setAttribute(l_record_element,'desc', r_dept.public1); 
l_record_node := dbms_xmldom.appendChild(l_dept_node,dbms_xmldom.makeNode(l_record_element)); 

мой выход:

<record_type desc="Public"/> 

Выход мне нужно:

<record_type desc="Public">PUBLIC</record_type> 

Спасибо!

Answer 1

Вам необходимо создать и добавить текстовый узел с значением PUBIC.

Демо показывает, что исходя из того же курсора, который обеспечивает тип записи:

set serveroutput on 

declare 
    l_domdoc dbms_xmldom.domdocument; 
    l_dept_node dbms_xmldom.domnode; 
    l_record_node dbms_xmldom.domnode; 
    l_record_element dbms_xmldom.domelement; 
    l_record_text dbms_xmldom.domtext; 
    l_tmp_node dbms_xmldom.domnode; 
    l_xmltype xmltype; 
    l_buffer varchar2(32767); 
begin 
    l_domdoc := dbms_xmldom.newDOMDocument; --(xmltype('<data />')); 

    for r_dept in (select 'Public' as public1, 'PUBLIC' as public2 from dual) loop 
    l_dept_node := dbms_xmldom.makeNode(l_domdoc); 

    -- code you showed 
    l_record_element := dbms_xmldom.createElement(l_domdoc, 'record_type'); 
    dbms_xmldom.setAttribute(l_record_element,'desc', r_dept.public1); 
    l_record_node := dbms_xmldom.appendChild(l_dept_node, dbms_xmldom.makeNode(l_record_element)); 
    -- add a text node 
    l_record_text := dbms_xmldom.createTextNode(l_domdoc, r_dept.public2); 
    l_tmp_node := dbms_xmldom.appendChild(l_record_node, dbms_xmldom.makeNode(l_record_text)); 

    -- display the node for demo 
    l_xmltype := dbms_xmldom.getXmlType(l_domdoc); 
    dbms_xmldom.freeDocument(l_domdoc); 
    dbms_output.put_line(l_xmltype.getClobVal); 
    end loop; 
end; 
/

<record_type desc="Public">PUBLIC</record_type> 

PL/SQL procedure successfully completed.