Jacoco online instrumentation Градиентный скрипт

Question

Я пробовал искать фрагменты сценария сценария Jacoco без инструментов, но не смог найти его. Можно ли использовать онлайн-инструменты Jacoco через сценарии градации? Если да ... Примером этого было бы здорово. Благодарю.

Answer 1

Плагин gradle jacoco не поддерживает автономную аппаратуру, он всегда делает онлайн-инструменты через java-агент.

Если муравей jacoco плагин поддерживает автономный инструментарий, который, вероятно, лучший способ, чтобы получить автономный инструментарий работы в Gradle

Answer 2

Вот пример Gradle сценария, который выполняет автономную аппаратуру с помощью JaCoCo задачи Ant:

apply plugin: 'java' 

configurations { 
    jacoco 
    jacocoRuntime 
} 

dependencies { 
    jacoco group: 'org.jacoco', name: 'org.jacoco.ant', version: '0.7.9', classifier: 'nodeps' 
    jacocoRuntime group: 'org.jacoco', name: 'org.jacoco.agent', version: '0.7.9', classifier: 'runtime' 
    testCompile 'junit:junit:4.12' 
} 

repositories { 
    mavenCentral() 
} 

task instrument(dependsOn: ['classes']) { 
    ext.outputDir = buildDir.path + '/classes-instrumented' 
    doLast { 
    ant.taskdef(name: 'instrument', 
       classname: 'org.jacoco.ant.InstrumentTask', 
       classpath: configurations.jacoco.asPath) 
    ant.instrument(destdir: outputDir) { 
     fileset(dir: sourceSets.main.output.classesDir) 
    } 
    } 
} 

gradle.taskGraph.whenReady { graph -> 
    if (graph.hasTask(instrument)) { 
    tasks.withType(Test) { 
     doFirst { 
     systemProperty 'jacoco-agent.destfile', buildDir.path + '/jacoco/tests.exec' 
     classpath = files(instrument.outputDir) + classpath + configurations.jacocoRuntime 
     } 
    } 
    } 
} 

task report(dependsOn: ['instrument', 'test']) { 
    doLast { 
    ant.taskdef(name: 'report', 
       classname: 'org.jacoco.ant.ReportTask', 
       classpath: configurations.jacoco.asPath) 
    ant.report() { 
     executiondata { 
     ant.file(file: buildDir.path + '/jacoco/tests.exec') 
     } 
     structure(name: 'Example') { 
     classfiles { 
      fileset(dir: sourceSets.main.output.classesDir) 
     } 
     sourcefiles { 
      fileset(dir: 'src/main/java') 
     } 
     } 
     html(destdir: buildDir.path + '/reports/jacoco') 
    } 
    } 
}