Вы установили довольно высокий заказ для заполнения TI-Basic. user3932000 верен; нет встроенной функции для создания входной формы типа, который вы запрашиваете.
Тем не менее, нет ничего, что помешало бы вам самим провести этот интерактивный интерфейс.Создание такого рода интерфейса с нуля будет трудоемким процессом для вас, а потребляющий память прессом для вашего калькулятора, поэтому он не стоит большую часть времени. Нет кода шаблона, в который вы вставляете переменные, чтобы получить желаемые результаты, но вам, возможно, удастся его моделировать после этого квадратичного решателя, который я написал.
ClrHome
a+bi
Output(1,1," QUADRATIC
Output(2,1," AX²+BX+C
Output(3,1,"ZEROS:
Output(6,1,"A=
Output(7,1,"B=
Output(8,1,"C=
DelVar YDelVar D
" →Str1
While Y≠105
getKey→Y
If Ans
Then
Output(X,4,Str1
Output(3,7,Str1+Str1+Str1+"
End
X+(Ans=34)-(Ans=25
If Ans<6:8
If Ans>8:6
Ans→X
Output(Ans,16,"◄
D(Y≠45→D
If Y=25 or Y=34
sum({A,B,C}(X={6,7,8→D
If Y=104:⁻D→D
10not(Y)+Y(102≠Y)-13int(Y/13(2>abs(5-abs(5-abs(Y-83
If Ans≤9
D10+Ans-2Ans(D<0→D
If X=6:D→A
If X=7:D→B
If X=8:D→C
If A
Then
2ˉ¹Aˉ¹(⁻B+{1,⁻1}√(B²-4AC
Else
If B
Then
⁻C/B
Else
If C
Then
"No Zeros
Else
"All Numbers
End
End
End
Output(3,7,Ans
Output(6,3,A
Output(7,3,B
Output(8,3,C
End
ClrHome
Ans
Это GIF того, что он делает для вас.
С немного больше работы. Этот код можно использовать на экране «График» вместо главного экрана, предоставляя больше возможностей с точки зрения макета и дизайна.
Немного разочаровывает, но спасибо за помощь, особенно с третьим пунктом. – Psifrost
'Prompt' обычно используется при вводе нескольких входов в разные переменные, потому что его можно использовать как' Prompt A, B, C', тогда как 'Input' не может. – Timtech
@Timtech Я предпочитаю «Input» A: «, A'' Input» B: «, B'' Input« C: », C' только потому, что мне нравятся мои дисплеи все красиво и красиво. – user3932000