содержание импорта из имен файлов, определенный в массиве

Question

я могу конкатенации файлов, считанных import во время компиляции, как это:

enum string a = import("a.txt"); 
enum string b = import("b.txt"); 
enum string result = a ~ b; 

Как я могу получить сцепленный result, если у меня есть имена файлов в массиве?

enum files = ["a.txt", "b.txt"]; 
string result; 
foreach (f; files) { 
    result ~= import(f); 
} 

Этот код с ошибкой Error: variable f cannot be read at compile time.

Функциональный подход, кажется, не работает, либо:

enum files = ["a.txt", "b.txt"]; 
enum result = reduce!((a, b) => a ~ import(b))("", files); 

Он возвращается с той же ошибкой: Error: variable b cannot be read at compile time

Answer 1

Я нашел решение, которое не использует строки Примеси:

string getit(string[] a)() if (a.length > 0) { 
    return import(a[0]) ~ getit!(a[1..$]); 
} 

string getit(string[] a)() if (a.length == 0) { 
    return ""; 
} 

enum files = ["a.txt", "b.txt"]; 
enum result = getit!files; 

Answer 2

Может быть, используя строковые Примеси?

enum files = ["test1", "test2", "test3"]; 

// There may be a better trick than passing the variable name here 
string importer(string[] files, string bufferName) { 
    string result = "static immutable " ~ bufferName ~ " = "; 

    foreach (file ; files[0..$-1]) 
     result ~= "import(\"" ~ file ~ "\") ~ "; 
    result ~= "import(\"" ~ files[$-1] ~ "\");"; 

    return result; 
} 

pragma(msg, importer(files, "result")); 
// static immutable result = import("test1") ~ import("test2") ~ import("test3"); 

mixin(importer(files, "result")); 
pragma(msg, result) 

Answer 3

@Tamas ответ.

Это может быть технически завернуто в одну функцию, используя static if, который, на мой взгляд, выглядит чище.

string getit(string[] a)() { 
    static if (a.length > 0) { 
     return import(a[0]) ~ getit!(a[1..$]); 
    } 
    else { 
     return ""; 
    } 
} 

Также технически

static if (a.length > 0) 

может быть

static if (a.length) 

Вы могли бы также объяснить неинициализированными массивов, как этот

string getit(string[] a)() { 
    static if (a && a.length) { 
     return import(a[0]) ~ getit!(a[1..$]); 
    } 
    else { 
     return ""; 
    } 
} 

Использование все равно будет то же самое.

enum files = ["a.txt", "b.txt"]; 
enum result = getit!files;