Game-Loop в Firemonkey для Android

Question

im в настоящее время делает 2D-игру в Firemonkey для моего телефона Android, используя некоторые элементы управления TImage и контролируя их позиции и углы. Просто как тот. Я пытался использовать свой обычный способ петли, который отлично работает/безупречен в Windows, но не работает на Android.

Способ № 1: «End-менее» петля (Bad)

Моя главная проблема заключается в том, что я хочу, чтобы избежать нежелательного/неожиданное поведение при использовании «конец бескоммутаторная петлю», как это, где у меня есть позвонить Application.ProcessMessages():

while (Game.IsRunning()) do 
begin 
    { Update game objects and stuff } 
    World.Update(); 


    { Process window messages, or the window will not respond anymore obviously } 
    Application.ProcessMessages(); { And thats what i want to avoid } 
end; 

проблема заключается в том, что, как им застрял в петле, а также вызова процедуры для обработки сообщений, я могу столкнуться с многими проблемами, а также я не думаю, что это хорошо путь.

Способ № 2: TTimer (Dont даже думать об этом ;-))

С TTimer ужасна во многих отношениях и не предназначены для использования такой вещи, подход, где я просто положить TTimer с минимальным интервалом. Кроме того, я никогда не пробовал другие Таймеры, чем это, но если есть один действительно для игр, я буду стараться это конечно :)

Метод # 3: OnIdle - Как я обычно делаю это на Windows,

На Windows Я могу использовать Application.OnIdle-Event.

procedure GameLoop(Sender: TObject; var Done: Boolean); 
begin 
    { Update game objects and stuff } 
    World.Update(); 

    { Set done to false } 
    Done := False; 
end; 

... 

Application.OnIdle := GameLoop; 

Он вызывается каждый раз, когда приложение простаивает над сообщениями Windows. Производительность кажется такой же или немного хуже, по сравнению с №1, а общая архитектура намного надежнее, поэтому я обычно использую этот метод. На Android, однако, кажется, что он называется по-разному в сочетании с TForm.MouseMove. Где в Windows OnIdle работает отлично, на Android он будет отставать/останавливаться, пока TForm.MouseMove вызывается с сенсорного ввода (RAD Studio компилирует его в события касания automaticlly)

Однако я могу запустить OnIdle самостоятельно в MouseMove Событие, позвонив по телефону Application.DoIdle и «помогите» в «Loop», где я думаю он пропускает beimg, но это работает и очень плохо и приносит снова нежелательное поведение и худшую производительность при работе с сенсорным вводом.

И это возвращает меня к методу №1, и, похоже, сейчас он работает лучше всего на Android. Есть ли другой способ создания надежного способа (постоянно и быстро называемого события типа OnIdle или так) создания такого цикла или любого способа избежать проблем, возникающих в методе №3 в сочетании с MouseMove-Events? Похоже, что Android-телефон не достаточно мощный, чтобы иметь достаточно «свободного времени» рядом с формами-событиями и обновлениями в мире.

Кроме того, можно ли использовать поток для мировой логики и рядом с ним метод # 1 в моей основной форме/потоке для обновления рендеринга? Безопасно ли обновлять элементы управления формы бесконечным циклом (с помощью Application.ProcessMessages()) и получать отображаемые данные из другого потока, работающего над миром, объектами и т. Д.?

Answer 1

Я думаю, что действительным вариантом является реализация TAnimation и переопределение ProcessAnimation. TAnimation автоматически назначается при запуске через TAnimator.

TGameLoop = class(TAnimation) 
    protected 
    procedure ProcessAnimation; override; 
    end; 
    [...] 
    procedure TGameLoop.ProcessAnimation; 
    begin 
    //call updates 
    end; 

и начал так:

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    FLoop := TGameLoop.Create(Self); 
    FLoop.Loop := True; 
    FLoop.Name := 'GameLoop'; 
    FLoop.Parent := Self; 
    TAnimator.StartAnimation(Self, 'GameLoop'); 
end; 

По умолчанию FPS установлен в 60 лет для анимации. Одна вещь, которую я не мог понять сейчас, - это вычислить Deltatime со времени последнего вызова, используя только свойства TAnimation. Это важно для работы с переменными временами. Но вы, холодный, сами используете System.Diagnostics.TStopwatch. Остановите часы в начале процесса ProcessAnimation и получите Ticks, запустите новый после завершения ProcessAnimation.

EDIT: Основной пример для Deltatime (Истекшее время с момента последнего вызова в секундах). Учитывая, что вы разместили ViewPort3D в Form1, добавлен TCube с именем Cube1, TGameLoop объявлен в том же подразделении, что и Form1 (я знаю, уродливый, но Demopurpose) и TGameLoop имеет поле FWatch типа TStopWatch.

procedure TGameLoop.ProcessAnimation; 
var 
    LDelta: Single; 
begin 
    FWatch.Stop; 
    LDelta := FWatch.ElapsedTicks/FWatch.Frequency; 
    Form1.Cube1.RotationAngle.Y := Form1.Cube1.RotationAngle.Y + 50*LDelta; 
    FWatch := TStopwatch.StartNew(); 
end; 

EDIT2: лучший пример, который распределяет ошибки округления/измерения в течение всего игрового периода жизни немного лучше. Вместо измерения только между вызовами мы измеряем с первого кадра. TGameLoop имеет новое поле FLastElapsedTicks (Двухместный)

procedure TGameLoop.FirstFrame; 
begin 
    FWatch := TStopWatch.StartNew(); 
end; 

procedure TGameLoop.ProcessAnimation; 
var 
    LDelta: Single; 
    LTickDelta, LElapsed: Double; 
begin 
    LElapsed := FWatch.ElapsedTicks; 
    LTickDelta := LElapsed - FLastElapsedTicks; 
    FLastElapsedTicks := LElapsed; 
    LDelta := LTickDelta/FWatch.Frequency; 
    Form1.Cube1.RotationAngle.Y := Form1.Cube1.RotationAngle.Y + 50*LDelta; 
end;