Ошибка при преобразовании битовых файлов в файлы туза

Question

Я хочу преобразовать файл .bit в файл .ace с помощью командной строки. Я пытаюсь создать файл .bat для этого. Но когда я выполняю команду, никакие файлы не добавляются в указанный каталог.

Пакетный файл с именем makeace и имеет следующий код:

@echo off 
if "%1" == "" goto error 
xmd -tcl ./genace.tcl -jprog -hw %1.bit -board ml505 -ace my_%1.ace 
goto end 
:error 
echo Makeace - by FPGA Developer http://www.fpgadeveloper.com 
echo. 
echo Usage: makeace bitfile (without .bit extension) 
echo Example: makeace project 
:end 
echo. 

Файл .BIT на мой тест был назван comp.bit.

Команда, используемая для тестирования было:

makeace comp 

Он работал без ошибок, но без добавления нового файла.

Что может быть ошибкой в ​​пакетном коде выше?

Answer 1

Я предлагаю использовать для пакетного файла:

@echo off 
if "%~1" == "" goto ShowHelp 
if "%~1" == "/?" goto ShowHelp 

rem Get just file name without file extension and path. 
set "BitFileName=%~n1" 
rem Get drive and path of file ending with a backslash. 
set "BitFilePath=%~dp1" 

xmd.exe -tcl ./genace.tcl -jprog -hw "%BitFilePath%%BitFileName%.bit" -board ml505 -ace "%BitFilePath%my_%BitFileName%.ace" 

set "BitFileName=" 
set "BitFilePath=" 
echo. 
goto :EOF 

:ShowHelp 
echo Makeace - by FPGA Developer http://www.fpgadeveloper.com 
echo. 
echo Usage: makeace bitfile 
echo. 
echo Example: makeace project 
echo. 
pause 

Теперь это не имеет значения, если пакетный файл вызывается с именем файла, имеющий .bit добавляется или нет. И теперь он работает также для имен файлов с 1 или более пробелами или другими символами, указанными на последней странице справки, путем запуска cmd /? в окне командной строки.

:EOF - это предопределенная метка, которая не должна быть явно определена в пакетном файле. goto :EOF, как exit /B, то есть выйти из этого командного файла и продолжить обработку команд в родительском процессе, что означает выход из командного процессора, если родительский процесс - это процесс команды cmd.exe, вызываемый без /K, чтобы открыть окно командной строки после завершения пакетной обработки.

Чтобы понять используемые команды и как они работают, откройте окно командной строки, выполните там следующие команды и внимательно прочитайте все страницы справки, отображаемые для каждой команды.

• call /? ... %~1 объясняет, %~n1 и %~dp1.
• echo /?
• goto /?
• if /?
• pause /?
• rem /?
• set /?