Сила поля развертки развертки не работает

Question

Я получил этот шейдер откуда-то, что я забыл, по умолчанию используется только сплошной цвет для ударяемого эффекта. поэтому я пытаюсь изменить его, чтобы он также поддерживал текстуру экрана.

Shader "TFTM/FX/Shield2" { 
    Properties { 
     _Position ("Collision", Vector) = (-1, -1, -1, -1)   
     _MaxDistance ("Effect Size", float) = 40   
     _ShieldColor ("Color (RGBA)", Color) = (0.7, 1, 1, 0) 
     _EmissionColor ("Emission color (RGBA)", Color) = (0.7, 1, 1, 0.01)   
     _EffectTime ("Effect Time (ms)", float) = 0 
     _MainTex ("Texture (RGB)", 2D) = "white" {} 
    } 

SubShader { 
    Tags { "Queue" = "Transparent" "RenderType" = "Transparent" } 
    LOD 2000 
    Cull Off 

    CGPROGRAM 
     #pragma surface surf Lambert vertex:vert alpha 
     #pragma target 3.0 

     struct Input { 
      float customDist; 
      float2 uv_MainTex; 
     }; 

     sampler2D _MainTex; 
     float4 _Position;   
     float _MaxDistance;   
     float4 _ShieldColor; 
     float4 _EmissionColor;   
     float _EffectTime; 

     float _Amount; 

     void vert (inout appdata_full v, out Input o) { 
      o.customDist = distance(_Position.xyz, v.vertex.xyz); 
      o.uv_MainTex = v.texcoord; 
     } 

     void surf (Input IN, inout SurfaceOutput o) { 
     o.Albedo = tex2D(_MainTex, IN.uv_MainTex).rgb;//_ShieldColor.rgb; 
     o.Emission = _EmissionColor; 

     if(_EffectTime > 0) 
     { 
      if(IN.customDist < _MaxDistance){ 
        o.Alpha = _EffectTime/500 - (IN.customDist/_MaxDistance) + _ShieldColor.a; 
        if(o.Alpha < _ShieldColor.a){ 
         o.Alpha = _ShieldColor.a; 
        } 
       } 
       else { 
        o.Alpha = _ShieldColor.a; 
       } 
      } 
      else{ 
       o.Alpha = o.Alpha = _ShieldColor.a; 
      } 
     } 

     ENDCG 
} 
Fallback "Transparent/Diffuse" 
} 

заменяю цвет с текстурой здесь

o.Albedo = tex2D (_MainTex, IN.uv_MainTex) .rgb; // _ ShieldColor.rgb;

но он не работает, он выглядит как один цвет вместо текстуры вокруг него.

Answer 1

Проблема с o.Aplha. В опубликованном шейдере surf возвращает Alpha независимо от текстуры, поэтому вам нужно изменить метод surf, чтобы установить выход Alpha на основе текстуры.

Это можно сделать так:

1) Заменить

o.Albedo = tex2D(_MainTex, IN.uv_MainTex).rgb;//_ShieldColor.rgb; 

с

// Read texture and set it to vector4 
half4 c = tex2D(_MainTex, IN.uv_MainTex); 
o.Albedo = c.rgb; 

2) Вставьте

o.Alpha *= c.a; 

после

else { 
    o.Alpha = o.Alpha = _ShieldColor.a; 
} 

Результат выглядит л так:

Полный код результата шейдер:

Shader "TFTM/FX/Shield2" { 
    Properties { 
     _Position("Collision", Vector) = (-1, -1, -1, -1) 
     _MaxDistance("Effect Size", float) = 40 
     _ShieldColor("Color (RGBA)", Color) = (0.7, 1, 1, 0) 
     _EmissionColor("Emission color (RGBA)", Color) = (0.7, 1, 1, 0.01) 
     _EffectTime("Effect Time (ms)", float) = 0 
     _MainTex("Texture (RGB)", 2D) = "white" {} 
    } 

    SubShader { 
     Tags { "Queue" = "Transparent" "RenderType" = "Transparent" } 
     LOD 2000 
     Cull Off 

    CGPROGRAM 
    #pragma surface surf Lambert vertex:vert alpha 
    #pragma target 3.0 

    struct Input { 
     float customDist; 
     float2 uv_MainTex; 
    }; 

    sampler2D _MainTex; 
    float4 _Position; 
    float _MaxDistance; 
    float4 _ShieldColor; 
    float4 _EmissionColor; 
    float _EffectTime; 

    float _Amount; 

    void vert(inout appdata_full v, out Input o) { 
     o.customDist = distance(_Position.xyz, v.vertex.xyz); 
     o.uv_MainTex = v.texcoord; 
    } 

    void surf(Input IN, inout SurfaceOutput o) { 
     half4 c = tex2D(_MainTex, IN.uv_MainTex); 
     o.Albedo = c.rgb;//_ShieldColor.rgb; 
     o.Emission = _EmissionColor; 

     if (_EffectTime > 0) 
     { 
      if (IN.customDist < _MaxDistance) { 
       o.Alpha = _EffectTime/500 - (IN.customDist/_MaxDistance) + _ShieldColor.a; 
       if (o.Alpha < _ShieldColor.a) { 
        o.Alpha = _ShieldColor.a; 
       } 
      } 
      else { 
       o.Alpha = _ShieldColor.a; 
      } 
     } 
     else { 
      o.Alpha = o.Alpha = _ShieldColor.a; 
     } 
     o.Alpha *= c.a; 
    } 

    ENDCG 
    } 
    Fallback "Transparent/Diffuse" 
}